MetaStock™ Zone Forum & FAQ Artykuły Linki Elliott Waves EasyLanguage™ Zone

A B C D E F G H I J K L M N O P R S T U V W Y Z #

30 Minute OHLC by Roy Larsen

=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=
From: dhruveshbhatt <dhruveshbhatt[at]yahoo.com>
To: equismetastock[at]yahoogroups.com <equismetastock[at]yahoogroups.com>
Date: Friday, January 20, 2006, 2:35:39 PM
Subject: [EquisMetaStock Group] INTRADAY 30 MIN CLOSE ON 5 MIN FORMULA

HELLO EVERYONE,

CAN ANYONE HELP ME TO GET METASTOCK CODE FOR 30 MINUTE CLOSE ON 5 MINUTE CHART.
IF ANYONE CAN HELP ME I WOULD BE HIGHLY OBLIGED

THANKYOU,
DHRUVESH BHATT

=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=
From: Roy Larsen <rlarsen[at]man.quik.co.nz>
To: equismetastock[at]yahoogroups.com <equismetastock[at]yahoogroups.com>
Date: Wednesday, January 25, 2006, 7:57:33 AM
Subject: [EquisMetaStock Group] INTRADAY 30 MIN CLOSE ON 5 MIN FORMULA

Dhruvesh

Did you get a reply to your request. If not, try this. You'll need to comment out O, H and L. The timing section is not proven yet and may need further work.

Regards

Roy
www.metastocktips.co.nz


30 Minute OHLC

{C2005 Roy Larsen, www.metastocktips.co.nz}
{for use on 1/5/10/15 minute charts}

{user options}
N:=Input("Plot 30 Minute OHLC",0,0,0);
Q:=Input("User Mode, 0=Static 1=Dynamic 2=Delayed",0,2,0);

{timing section for longer frames}
A:=Minute(); B:=Hour()*60+A-1; J:=Int(B/30);
G:=LastValue(Highest(A)<=30);
D:=DayOfWeek()<>ValueWhen(2,1,DayOfWeek());
M:=J<>ValueWhen(2,1,J) OR D OR G;
F:=J-ValueWhen(2,1,J)>1 OR (Frac(A/30)=0)*(D=0) OR G;
A:=LastValue(Cum(1)-1)=Cum(1);
B:=ValueWhen(2,1,A);
J:=If(F,1,If(Alert(F,2)=0 AND M,2,0));
J:=If(A+LastValue(J)>2 OR B+(Q=1)=2,1,J);
J:=If(G,1,If(Q=2 OR Cum(J)<=1,M*2,J));

{Prices for longer frames}
Oo:=ValueWhen(1,M,O);
Oo:=ValueWhen(1,J,If(J=1,Oo,ValueWhen(2-G,1,Oo)));
Hh:=HighestSince(1,M,H);
Hh:=ValueWhen(1,J,If(J=1,Hh,ValueWhen(2-G,1,Hh)));
Ll:=LowestSince(1,M,L);
Ll:=ValueWhen(1,J,If(J=1,Ll,ValueWhen(2-G,1,Ll)));
K:=ValueWhen(1,J,If(J=1,C,ValueWhen(2-G,1,C)));
Oo:=ValueWhen(1,Oo>0,Oo);
Hh:=ValueWhen(1,Hh>0,Hh);
Ll:=ValueWhen(1,Ll>0,Ll);

{Build function for longer frames here}

{Plot results}
Oo; Hh; Ll; K; {Frame OHLC}



 

Source / From: TOP
Metastockusers[at]yahoogroups[dot]com

Equis and MetaStock® and MetaStock Professional® are registered trademarks of Equis International. Achelis Binary Wave®, The DownLoader®,
Expert Advisor®, OptionScope®, Quotecenter® and Smart Charts® are trademarks of Equis International, a Thomson Reuters company.

TradeStation® Pro, TradeStation® 2000i, OptionStation®, SuperCharts®, PowerEditor® and EasyLanguage®
are registered trademarks of TradeStation Technologies, Inc. Other names and marks referred to are the property of their respective owners.

All information provided on this website is for educational purposes only. Trading involves risk, including possible loss of principal and other losses.

Ten i inne materiały na tej stronie zostały zamieszczone zostały jedynie w celach edukacyjnych, nie ponoszę żadnej odpowiedzialno¶ci za ich stosowanie.

Gra na giełdzie i rynkach walutowych (FOREX) niesie ze sob± ryzyko poważnych strat finansowych!