MetaStock™ Zone Forum & FAQ Artykuły Linki Elliott Waves EasyLanguage™ Zone

A B C D E F G H I J K L M N O P R S T U V W Y Z #

Tema PV Binary Wave
PV Binary Wave

· To: "Francois Martin" <francoisma@xxxxxxxxx>, "Metastock" <metastock@xxxxxxxxxxxxx>
· Subject: PV Binary Wave
· From: "Jim Greening" <JimGinVA@xxxxxxxxxxxxx>
· Date: Sat, 22 Aug 1998 18:25:34 -0400
· Reply-To: metastock@xxxxxxxxxxxxx
· Sender: owner-metastock@xxxxxxxxxxxxx

All,
I've been thinking about developing a binary wave and a binary wave system test based on price and volume patterns only to supplement my indicator binary wave composite. I don't want to use any indicators except price and volume. I'm hoping to use all the old sayings such as higher highs and higher lows are bullish, breakouts and big moves on large volume, etc. I'd like to develop this binary wave and test with help from everyone on the list who is interested. Maybe we can all learn something and come up with a useful system.

To develop the binary wave and test sensitivity of any proposed component, I'd like to use a simple zero crossover test. After the binary wave is developed, we can experiment with ideas to make the system test more useful. So to start off the system test will be:

Enter Long

Fml("Tema PV Binary Wave") > 0

Enter Short

Fml("Tema PV Binary Wave") < 0

we don't need anything more complicated then this to develop the binary wave.

The first idea I tried was the old idea that higher highs and higher lows are bullish and lower lows and lower highs are bearish. I decided that it made sense to test for short, intermediate, and long term indications. I've used 21, 55, and 233 days for short, intermediate, and long term moving averages for years, so that's what I decided to start with. My first idea for a bullish formula was as follows:

PVBW01 (Higher Highs & Lows)

If(HHV(L,8) = HHV(L,21),1,0) +
If(HHV(L,21) = HHV(L,55),1,0) +
If(HHV(L,55) = HHV(L,233),1,0) +
If(HHV(H,8) = HHV(H,21),1,0) +
If(HHV(H,21) = HHV(H,55),1,0) +
If(HHV(H,55) = HHV(H,233),1,0)

The idea here is to see if the highest value is achieved in the last part of the period. If it is, then we can say that the highs and lows are rising for the period being looked at. Any time the condition is true, we get a value of 1, anytime it is false, we get a value of 0. The formula then adds the result so the total will be a whole number between 0 and 6. I then plotted that formula above several stocks and tested it with the simple binary wave test and found that it did perform fairly well.

I then thought about my actual trading and realized that I generally give more weight to longer term trends. Therefore, I played with the formula to give more weight to the longer terms and ended up with the following for thew first component of my PV binary wave:

PVBW01

{Higher Highs and Lows}
If(HHV(L,8) = HHV(L,21),1,0) +
If(HHV(L,21) = HHV(L,55),2,0) +
If(HHV(L,55) = HHV(L,233),3,0) +
If(HHV(H,8) = HHV(H,21),1,0) +
If(HHV(H,21) = HHV(H,55),2,0) +
If(HHV(H,55) = HHV(H,233),3,0)

 

I then decided to use the mirror image for a bearish formula

PVBW02

{Lower Highs & Lows}
If(LLV(H,8) = LLV(H,21),-1,0) +
If(LLV(H,21) = LLV(H,55),-2,0) +
If(LLV(H,55) = LLV(H,233),-3,0) +
If(LLV(L,8) = LLV(L,21),-1,0) +
If(LLV(L,21) = LLV(L,55),-2,0) +
If(LLV(L,55) = LLV(L,233),-3,0)

 

Of course we need to add all the components together to get a binary wave so my first attempt at a PV binary wave formula was as follows:

PVBW Add

Fml("PVBW01") + Fml("PVBW02")

My next though was how to use an up move on high volume as bullish, a down move on high volume as bearish. I finally came up with:

PVBW03

{High V Up Move}
If(Mov(V,3,S) > 1.13*Mov(V,21,S),1,0) * If(C > Ref(H,-1),3,0)

 

This formula will return a zero if the volume is less then 1.13 times the 21 day simple moving average or if the close is less then yesterday's high. It returns a plus 3 (bullish) if the volume is more then 1.13 times the 21 day moving average and the close is higher then yesterday's high. I use the mirror image for the bearish condition:

PVBW04

{High V Down Move}
If(Mov(V,2,S) > 1.13*Mov(V,21,S),1,0) * If(C < Ref(L,-1),-3,0)

 

The Binary Wave formula now becomes:

PVBW Add

Fml("PVBW01") + Fml("PVBW02") + Fml("PVBW03") + Fml("PVBW04")

My final thought was to give quite a bit of bullish weight for new high volume 233 day highs or bearish weight for high volume 233 day lows. The formulas doing that are pretty straight forward and are:

PVBW05

{New 233 Day High}
((If(Mov(V,2,S) > 1.13*Mov(V,21,S),1,0)) * If((H = HHV(H,233)),7,0))

 


PVBW06

{New 233 Day Low}
((If(Mov(V,2,S) > 1.13*Mov(V,21,S),1,0)) * If((L = LLV(L,233)),-7,0))

 

The Binary Wave formula now becomes:

PVBW Add

Fml("PVBW01") + Fml("PVBW02") + Fml("PVBW03") +
Fml("PVBW04") + Fml("PVBW05") + Fml("PVBW06")

Finally, I'd like to smooth the binary wave, so I'll use the Tema function for that and my final test binary wave is:

Tema PV Binary Wave

Tema(Fml("PVBW Add"),34)

That's as far as I've gotten. I'm attaching a MetaStock V6.5 self extracting import file with the formulas and test. Just double click on the file and tell it to unzip to a blank subdirectory or floppy. The instructions on importing are on page 215 of your manual. I'd appreciate it if you would test the wave against several of your stocks and make suggestions on changing any of the formulas I presented. Also, I'd like your ideas for additional components. Please restrict those ideas to price and volume relationships only.

Thanks!
Jim

[7498]

PV Binary Wave

. To: "Metastock" <metastock@xxxxxxxxxxxxx>
. Subject: PV Binary Wave
. From: "Jim Greening" <JimGinVA@xxxxxxxxxxxxx>
. Date: Mon, 24 Aug 1998 19:15:19 -0400
. Reply-To: metastock@xxxxxxxxxxxxx
. Sender: owner-metastock@xxxxxxxxxxxxx

All,
I'm playing with a look back component for the binary wave based on several comments and suggestions that I've received. The one I'm using now is:

PVBW07

{Price Look Back}
If(C>=Ref(C,-13),1,-1) +
If(C>=Ref(C,-15),1,-1) +
If(C>=Ref(C,-17),1,-1) +
If(C>=Ref(C,-19),1,-1) +
If(C>=Ref(C,-21),1,-1)

 

The Binary Wave formula now becomes:

PVBW Add

Fml("PVBW01") + Fml("PVBW02") +
Fml("PVBW03") + Fml("PVBW04") +
Fml("PVBW05") + Fml("PVBW06") +
Fml("PVBW07")

 


Tema PV Binary Wave

Tema(Fml("PVBW Add"),34)

 
e-w-Tema_PV_Binary_Wave.gif
 
I'd appreciate it if you all would play with it and offer suggestions for improvements.

Jim

[7615]
Source / From: TOP
http://purebytes.com/archives/metastock/

Equis and MetaStock® and MetaStock Professional® are registered trademarks of Equis International. Achelis Binary Wave®, The DownLoader®,
Expert Advisor®, OptionScope®, Quotecenter® and Smart Charts® are trademarks of Equis International, a Thomson Reuters company.

TradeStation® Pro, TradeStation® 2000i, OptionStation®, SuperCharts®, PowerEditor® and EasyLanguage®
are registered trademarks of TradeStation Technologies, Inc. Other names and marks referred to are the property of their respective owners.

All information provided on this website is for educational purposes only. Trading involves risk, including possible loss of principal and other losses.

Ten i inne materiały na tej stronie zostały zamieszczone zostały jedynie w celach edukacyjnych, nie ponoszę żadnej odpowiedzialno¶ci za ich stosowanie.

Gra na giełdzie i rynkach walutowych (FOREX) niesie ze sob± ryzyko poważnych strat finansowych!